15.4.1403  src/lib/x-kit/widget/edit/float-millout.pkg

## float-millout.pkg
#

# Compiled by:
#     src/lib/x-kit/widget/xkit-widget.sublib


stipulate
    include package   threadkit;                                                # threadkit                     is from   src/lib/src/lib/thread-kit/src/core-thread-kit/threadkit.pkg
    #
    package mt  =  millboss_types;                                              # millboss_types                is from   src/lib/x-kit/widget/edit/millboss-types.pkg

    nb = log::note_on_stderr;                                                   # log                           is from   src/lib/std/src/log.pkg
herein

    package float_millout                                                       # 
    {
        Float_Millout
          =     
          { note_watcher:  (mt::Inport, Null_Or(mt::Millin), (mt::Outport, Float) -> Void) -> Void,     # Second arg will be NULL if watcher is not another mill (e.g. a pane).
            drop_watcher:   mt::Inport -> Void                                                          # The mt::Inport must match that given to note_watcher.
          };                             

        exception  FLOAT_MILLOUT  Float_Millout;                                # We'll never 'raise' this exception:  It is purely a datastructure to hide the Float_Millout type from millboss-imp.pkg, in the interests of good modularity.
        #
        #
        fun maybe_unwrap__float_millout  (watchable:  mt::Millout):  Fail_Or( Float_Millout )
            =
            case watchable.crypt
                #
                FLOAT_MILLOUT
                float_millout
                    =>
                    WORK float_millout;

                _   =>  FAIL (sprintf "maybe_unwrap__float_millout:  Unknown Millout value, port_type='%s', data_type='%s' info='%s'  --float-millout.pkg"
                                        watchable.port_type 
                                        watchable.data_type 
                                        watchable.info
                             );
            esac;       

        fun unwrap__float_millout  (watchable:  mt::Millout):   Float_Millout
            =
            case watchable.crypt
                #
                FLOAT_MILLOUT
                float_millout
                    =>
                    float_millout;

                _   =>  {   msg = (sprintf "maybe_unwrap__float_millout:  Unknown Millout value, port_type='%s', data_type='%s' info='%s'  --float-millout.pkg"
                                        watchable.port_type 
                                        watchable.data_type 
                                        watchable.info
                                  );
                            log::fatal msg;                                                     # Won't return.
                            raise exception DIE msg;                                            # Just to keep compiler happy.
                        };
            esac;       


        port_type =  "float_millout::Float_Millout";                                            # Export so clients can use this value by reference instead of duplication (with attendant maintenance issues).

        fun wrap__float_millout
              (
                outport:        mt::Outport,
                float_millout:  Float_Millout
              ):                mt::Millout
            =
            { outport,
              port_type,
              data_type =>  "Float",
              info      =>  "Wrapped by float_millout::wrap__float_millout.",
              crypt     =>  FLOAT_MILLOUT float_millout,
              counter   =>  REF 0       
            };           
    };

end;