15.4.1404  src/lib/x-kit/widget/edit/floats-millout.pkg

## floats-millout.pkg
#

# Compiled by:
#     src/lib/x-kit/widget/xkit-widget.sublib


stipulate
    include package   threadkit;                                                                # threadkit                     is from   src/lib/src/lib/thread-kit/src/core-thread-kit/threadkit.pkg
    #
    package mt  =  millboss_types;                                                              # millboss_types                is from   src/lib/x-kit/widget/edit/millboss-types.pkg

#   package im  =  int_red_black_map;                                                           # int_red_black_map             is from   src/lib/src/int-red-black-map.pkg
#   package is  =  int_red_black_set;                                                           # int_red_black_set             is from   src/lib/src/int-red-black-set.pkg
    package sm  =  string_map;                                                                  # string_map                    is from   src/lib/src/string-map.pkg

    nb = log::note_on_stderr;                                                                   # log                           is from   src/lib/std/src/log.pkg
herein

    package floats_millout                                                                      # 
    {
        Floats
          =
          { units:              Null_Or(String),
            floats:             sm::Map(Float)
          };

        Floats_Millout
          =     
          { note_watcher:       (mt::Inport, Null_Or(mt::Millin), (mt::Outport, Floats) -> Void) -> Void,               # Second arg will be NULL if watcher is not another mill (e.g. a pane).
            drop_watcher:        mt::Inport -> Void                                                                     # The mt::Inport must match mt::Milling.inport given to note_watcher.
          };                             

        exception  FLOATS_MILLOUT  Floats_Millout;                                              # We'll never 'raise' this exception:  It is purely a datastructure to hide the Floats_Millout type from millboss-imp.pkg, in the interests of good modularity.
        #
        #
        fun maybe_unwrap__floats_millout  (watchable:  mt::Millout):  Fail_Or( Floats_Millout )
            =
            case watchable.crypt
                #
                FLOATS_MILLOUT
                floats_millout
                    =>
                    WORK floats_millout;

                _   =>  FAIL (sprintf "maybe_unwrap__floats_millout:  Unknown Millout value, port_type='%s', data_type='%s' info='%s'  --floats-millout.pkg"
                                        watchable.port_type 
                                        watchable.data_type 
                                        watchable.info
                             );
            esac;       

        fun unwrap__floats_millout  (watchable:  mt::Millout):   Floats_Millout
            =
            case watchable.crypt
                #
                FLOATS_MILLOUT
                floats_millout
                    =>
                    floats_millout;

                _   =>  {   msg = (sprintf "maybe_unwrap__floats_millout:  Unknown Millout value, port_type='%s', data_type='%s' info='%s'  --floats-millout.pkg"
                                        watchable.port_type 
                                        watchable.data_type 
                                        watchable.info
                                  );
                            log::fatal msg;                                                     # Won't return.
                            raise exception DIE msg;                                            # Just to keep compiler happy.
                        };
            esac;       


        port_type =  "floats_millout::Floats_Millout";                                          # Export so clients can use this value by reference instead of duplication (with attendant maintenance issues).

        fun wrap__floats_millout
              (
                outport:        mt::Outport,
                floats_millout: Floats_Millout
              ):                mt::Millout
            =
            { outport,
              port_type,
              data_type =>  "floats_millout::Floats",
              info      =>  "Wrapped by floats_millout::wrap__floats_millout.",
              crypt     =>  FLOATS_MILLOUT floats_millout,
              counter   =>  REF 0       
            };           
    };

end;