15.4.1407  src/lib/x-kit/widget/edit/int-millout.pkg

## int-millout.pkg
#

# Compiled by:
#     src/lib/x-kit/widget/xkit-widget.sublib


stipulate
    include package   threadkit;                                                # threadkit                     is from   src/lib/src/lib/thread-kit/src/core-thread-kit/threadkit.pkg
    #
    package mt  =  millboss_types;                                              # millboss_types                is from   src/lib/x-kit/widget/edit/millboss-types.pkg

    nb = log::note_on_stderr;                                                   # log                           is from   src/lib/std/src/log.pkg
herein

    package int_millout                                                         # 
    {
        Int_Millout
          =     
          { note_watcher:  (mt::Inport, Null_Or(mt::Millin), (mt::Outport, Int) -> Void) -> Void,       # Second arg will be NULL if watcher is not another mill (e.g. a pane).
            drop_watcher:   mt::Inport -> Void                                                          # The mt::Inport must match that given to note_watcher.
          };                             

        exception  INT_MILLOUT  Int_Millout;                                    # We'll never 'raise' this exception:  It is purely a datastructure to hide the Int_Millout type from millboss-imp.pkg, in the interests of good modularity.
        #
        #
        fun maybe_unwrap__int_millout  (watchable:  mt::Millout):  Fail_Or( Int_Millout )
            =
            case watchable.crypt
                #
                INT_MILLOUT
                int_millout
                    =>
                    WORK int_millout;

                _   =>  FAIL (sprintf "maybe_unwrap__int_millout:  Unknown Millout value, port_type='%s', data_type='%s' info='%s'  --int-millout.pkg"
                                        watchable.port_type 
                                        watchable.data_type 
                                        watchable.info
                             );
            esac;       

        fun unwrap__int_millout  (watchable:  mt::Millout):   Int_Millout
            =
            case watchable.crypt
                #
                INT_MILLOUT
                int_millout
                    =>
                    int_millout;

                _   =>  {   msg = (sprintf "maybe_unwrap__int_millout:  Unknown Millout value, port_type='%s', data_type='%s' info='%s'  --int-millout.pkg"
                                        watchable.port_type 
                                        watchable.data_type 
                                        watchable.info
                                  );
                            log::fatal msg;                                                     # Won't return.
                            raise exception DIE msg;                                            # Just to keep compiler happy.
                        };
            esac;       


        port_type =  "int_millout::Int_Millout";                                                # Export so clients can use this value by reference instead of duplication (with attendant maintenance issues).

        fun wrap__int_millout
              (
                outport:        mt::Outport,
                int_millout:    Int_Millout
              ):                mt::Millout
            =
            { outport,
              port_type,
              data_type =>  "Int",
              info      =>  "Wrapped by int_millout::wrap__int_millout.",
              crypt     =>  INT_MILLOUT int_millout,
              counter   =>  REF 0       
            };           
    };

end;